엑셀 두가지 조건 만족 IF - egsel dugaji jogeon manjog IF

지금 예제에서는 평균점수를 미리 구해서
구해진 평균점수로 
합격/불합격여부를 구했는데
평균점수를 굳이 따로 안구할거라면
=IF(AND(AVERAGE(D5:F5)>=70,F5>=80),"합격","불합격")
이렇게 바로 입력을 하면 됩니다.

여기서 또다른 TIP을 드리자면,
※if와 and함수뿐만 아니라
모든 두가지 이상의 함수를 사용할때는 
안쪽에 있는 함수부터 입력하고, 
바깥쪽 함수 입력하면 
이해하기 쉬워요 ^^
적응되면 그냥 앞으로부터
입력하면 되겠죠

이문제에서는
AND함수부터 입력해보세요. 
I3셀에
=AND(H3>=70,F3>=80) 입력하면
false라고 나오죠~
나중에 AND함수 바깥에 
IF함수를  씌워주는겁니다.
=IF(AND(H3>=70,F3>=80),"합격","불합격")
이렇게요.

동영상으로 보여드릴게요~!

엑셀 IF 다중조건 목차 바로가기

1. 엑셀 IF함수의 모든 것 - 라이브 풀영상
2. 사용된 공식 요약
3. 예제파일 다운로드
4. 엑셀 IF 다중조건 공식 설명
   3-1. IF 함수 기초
   3-2. AND 조건
   3-3. OR 조건
   3-4. IF 함수 다중조건
5. IF 함수 다중조건 공식 사용시 주의사항
6. IF 함수 다중조건 공식을 VLOOKUP함수로 대체하는 방법 

함수 공식

A와 B를 모두 만족할 때, 결과를 출력! (→ IF함수 AND조건)

= IF(AND(조건1, 조건2...),참일경우결과,거짓일경우결과)

■ 평균이 60점 이상이고, 최소 점수가 40점 이상이면 통과
= IF(AND(AVERAGE(점수)>=60,MIN(점수)>40)),"통과","재시험")

A 또는 B 둘 중 하나라도 만족하면, 결과를 출력! (→ IF함수 OR조건)

= IF(OR(조건1,조건2...),참일경우결과,거짓일경우결과)

■ 토익 900점 이상이거나 토플 100점 이상이면 "통과"
= IF(OR(토익점수>=900,토플점수>=100),"통과","자격미달")

A 이면 결과1, B 이면 결과2, C이면 결과3, 나머지는 결과4를 출력! (→ IF함수 다중조건)

= IF(조건1,결과1,IF(조건2,결과2,IF(조건3,결과3,나머지결과)))

■ 국적이 한국이면 한국어, 일본이면 일본어, 중국이면 중국어, 나머지 지역은 영어를 출력
= IF(국적="한국","한국어",IF(국적="일본","일본어",IF(국적="중국","중국어","영어")))

예제파일 다운로드

오빠두엑셀의 강의 예제파일은 여러분을 위해 자유롭게 제공하고 있습니다.

라이브 강의 전체영상도 함께 확인해보세요!

위캔두 회원이 되시면 매주 오빠두엑셀에서 진행하는 라이브강의 풀영상을 확인하실 수 있습니다.

사용된 기초 함수

엑셀 IF 다중조건 공식 알아보기

공식 설명

엑셀 IF 함수 다중조건 공식은 각 조건에 서로 다른 결과를 출력할 때 사용하는 공식입니다. 실무에서는 여러 상황이 발생하므로, 이번 포스트에서 소개해드린 기본 공식을 익힌 다음, 각 상황에 맞춰 적절히 응용하는 것이 좋습니다.

IF 함수 다중조건 공식은 크게 3가지로 구분할 수 있습니다.

IF 함수 기초

IF 함수는 엑셀 뿐만 아니라 모든 프로그래밍 언어에서 사용되는 필수 함수입니다. 엑셀에서는 기초 논리연산 뿐만 아니라 다양한 고급 배열수식을 작성하기 위해 반드시 알아야 할 실무자 필수 함수인데요.

우선 IF 함수의 기본 동작 원리를 알아보겠습니다. 수중에 가지고 있는 돈이 6,500원이고 식당에서 음식을 주문한다면 IF 함수를 아래처럼 작성할 수 있습니다.

=IF(가격<=6,500,"주문한다","다른메뉴를주문")

• [조건] 가격 <= 6,500
• [참일경우결과] 주문한다
• [거짓일경우결과] 다른 메뉴를 주문한다

하지만 메뉴판을 보면, 김치찌개, 순두부찌개, 등.. 6,500원 이하인 식사 메뉴도 있지만 밑에 주류 항목으로 소주, 맥주, 막걸리 또한 6,500원 이하 메뉴에 포함됩니다. 이럴 경우, 가격이 6,500원 이하이면서 메뉴가 식사인 경우만 주문하도록 조건을 추가해야 합니다.

이렇게 하나의 조건만으로 원하는 결과를 얻을 수 없을 때, AND조건/OR조건/다중조건으로 IF 함수를 작성해서 원하는 결과를 얻어낼 수 있습니다.

IF 다중 조건 공식1. AND 조건

IF 함수 AND 조건 공식은 여러 조건을 모두 만족하면 참인 결과를 출력하는 공식입니다.

=IF(AND(조건1,조건2...),참일경우결과,거짓일경우결과)
'조건1, 조건2를 모두 만족하면 참, 그렇지 않으면 거짓을 출력합니다.

실무에서 AND 조건 공식을 활용하는 대표예제는 아래와 같습니다.

1. 식당에서 메뉴 정하기

   '가격이 6,500원 이하이고, 종류가 식사류일 경우 "주문", 그렇지 않으면 "주문안함"
   =IF(AND(가격<=6,500,종류="식사류"),"주문","주문안함")

2. 신규 매장 후보지 결정

   '매장 면적이 50sqm 이상이고 월세가 500만원 이하인 경우 "후보지", 그렇지 않으면 "미달"
   =IF(AND(매장면적>=50, 월세<=5,000,000),"후보지","미달")

3. 공무원 시험 합격자 결정

   '모든 과목의 평균 점수가 60점 이상이고, 최소 점수가 40점 이상(과락)이면 "통과", 그렇지 않으면 "탈락"
   =IF(AND(AVERAGE(점수)>=60,MIN(점수)>=40),"통과","탈락")

오빠두Tip : AND 조건을 계산식으로 표현하면 곱셈(*)과 동일합니다. IF 함수 배열수식에 주로 사용하는 방법인데요.
예를 들어 A1:A5 범위의 값이 "식사류" 이고, B1:B5의 값이 6,500원 이하인 경우, 가격의 평균을 구하면 아래와 같이 작성됩니다.(=AVERAGEIFS 와 동일)

'A1:A5 = {"식사류","주류","식사류","식사류","주류"}
'B1:B5 = {7000, 3500, 6000, 5500, 5000}
=AVERAGE(IF((A1:A5="식사류")*(B1:B5<=6,500),B1:B5,0))
=AVERAGE(IF({TRUE,FALSE,TRUE,TRUE,FALSE}*{FALSE,TRUE,TRUE,TRUE,TRUE},{7000, 3500, 6000, 5500, 5000},0)
=AVERAGE(IF({0,0,1,1,0},{7000, 3500, 6000, 5500, 5000},0)
=AVERAGE({0,0,6000,5500,0})
=5,750

IF 다중 조건 공식2. OR 조건

IF 함수 OR 조건 공식은 여러 조건 중 하나라도 만족하면 참인 결과를 출력하고 그렇지 않으면 거짓을 출력하는 공식입니다.

=IF(OR(조건1,조건2...),참일경우결과,거짓일경우결과)
'조건1, 조건2 중 하나라도 만족하면 참, 그렇지 않으면 거짓을 출력합니다.

실무에서 OR 조건 공식을 사용하는 대표예제는 아래와 같습니다.

1. 인사고과 평가를 위한 통과/미달 여부 평가

   '외국어 점수 90점 이상이거나 봉사활동 시간 30시간 이상이면 "통과", 그렇지 않으면 "미달"
   =IF(OR(외국어점수>=90,봉사활동시간>=30),"통과","미달")

2. 정부지원금 신청 가능 여부 조회

   '작년대비 매출액이 30%이상 감소했거나 올해 월 매출액이 250만원 이하면 "신청가능", 그렇지 않으면 "신청불가"
   =IF(OR((올해매출-작년매출)/작년매출<=-30%,올해매출<=250),"신청가능","신청불가")

3. 기내 수하물 휴대 가능여부 조회

   '무게가 10kg 이상이거나 삼변의 합이 115cm 이상이면 "휴대불가", 그렇지 않으면 "휴대가능"
   =IF(OR(무게>=10,(높이+깊이+너비)>=115),"휴대불가","휴대가능")

오빠두Tip : OR 조건을 계산식으로 표현하면 덧셈(+)과 동일합니다. 즉 AND조건(=곱셈)과 OR조건(=덧셈)을 IF함수 배열수식에 적절히 활용하면 상황에 따라 다양한 고급공식을 작성할 수 있습니다.
예를 들어 A1:A10 범위의 값이 "인사팀" 이거나 "재무팀" 인 개수는 아래 수식으로 구할 수 있습니다. =COUNTIF+COUNTIF 와 동일)

'A1:A10 = {"인사팀","IT팀","영업팀","재무팀","인사팀","재무팀","영업팀","개발팀","물류팀","재무팀"}
=SUM(IF((A1:A10="인사팀")+(A1:A10="재무팀"),1,0))
=SUM(IF({TRUE,FALSE,FALSE,TRUE,TRUE,TRUE,FALSE,FALSE,FALSE,TRUE},1,0))
=SUM({1,0,0,1,1,1,0,0,0,1})
=5

IF 다중 조건 공식3. 다중 조건 혼합

IF 함수 다중조건 공식은 여러 조건을 비교해서 각 조건마다 다른 결과를 출력할 때 사용하는 공식입니다. 기본 공식은 아래와 같습니다.

=IF(조건1,결과1,IF(조건1,결과2,IF(조건3,결과3,나머지결과)))
'조건1, 조건2 중 하나라도 만족하면 참, 그렇지 않으면 거짓을 출력합니다.

오빠두Tip : 엑셀 2019 이후 또는 365 버전을 사용중이시라면, IFS 함수를 사용해서 IF 함수 다중조건 공식을 더욱 편리하게 입력할 수 있습니다.

=IFS(조건1,결과1,조건2,결과2,조건3,결과4,...,TRUE,나머지결과)

하지만 IFS 함수는 엑셀 2016 이전 버전과는 호환되지 않습니다. 따라서 여러 사람과 공유하는 파일일 경우 IF 함수 다중조건 공식을 사용하는 것이 좋습니다.

실무에서 IF 함수 다중조건을 적용하는 대표 예제는 아래와 같습니다.

1. 시험 점수 별 성적 나누기

   '90점 이상=A, 80점이상=B, 70점이상=C, 나머지=D
   =IF(점수>=90,"A",IF(점수>=80,"B",IF(점수>=70,"C","D")))

2. 제품코드별 상품 카테고리 나누기

   '앞 2자리 기준,
   'AA=남성복, BB=여성복, CC=남녀공용, DD=아동용
   =IF(LEFT(코드,2)="AA","남성복",IF(LEFT(코드,2)="BB","여성복",IF(LEFT(코드,2)="CC","남녀공용","아동용")))

3. 체력검사 성적별 신체등급 나누기 (AND 함수 응용)

   '팔굽혀펴기(A), 윗몸일으키기(B) 성적 기준
   'A>50,B>50: 특급
   'A>40,B>35: 우수
   'A>30,B>20: 보통
   '그 외 : 미달
   =IF(AND(A>50,B>50),"특급",IF(AND(A>40,B>35),"우수",IF(AND(A>30,B>20),"보통","미달")))

IF 함수 다중 조건 공식 사용시 주의사항

IF 함수 다중 조건 공식은 반드시 최상위 또는 최하위 조건부터 차례대로 작성해야 합니다. 예를 들어, 시험 점수별로 성적을 나눌 경우 조건은 아래와 같이 2가지로 작성할 수 있습니다.

최상위 조건부터 볼 경우

' 90점이상=A, 80점이상=B, 70점이상=C, 그외=D
=IF(점수>=90,"A",IF(점수>=80,"B",IF(점수>=70,"C","D")))

최하위 조건부터 볼 경우

하지만 조건을 아래와 같이 작성하면, 첫번째 조건과 두번째 조건이 겹치게 되어 잘못된 결과가 계산됩니다.

IF 함수 다중 조건 공식을 편리하게 사용하는 방법

IF 함수 다중조건 공식은 실무에서 다양한 상황에 적용할 수 아주 유용한 공식이지만, 한가지 고려해야 할 사항이 있습니다. 바로 비교 조건이 5개 이상 들어갈 경우, 공식이 복잡해지는 문제인데요.

만약 IF 함수 다중조건으로 "특정 값과 같을 경우(=)"가 여러개 입력되는 상황이라면, IF 함수 다중조건 대신 VLOOKUP 함수를 사용하는 것이 더욱 편리하게 수식을 작성할 수 있습니다.

오빠두Tip : 만약 연속된 숫자의 크기를 비교하는 IF함수 다중조건이라면, VLOOKUP 함수 유사일치 조건을 사용하면 수식을 보다 편리하게 작성할 수 있습니다. (예: 소득세 구간 나누기 등)

관련 링크 : MS 홈페이지 IF 함수 다중조건 공식 설명